7.제어문
조건문
조건문은 실행중에 조건을 판단하여 실행 여부를 결정하거나 실행할 명령을 선택한다. 명령문을 순서대로만 실행하는 것이 아니라 선택적으로 실행하여 스크립트의 동작에 지능을 부여하는 제어문이다. 기본 형식은 C나 자바와 같다. 다음 코드는 사용자에게 질문 후 삭제 여부를 선택한다.
F1::
{
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes")
{
Send "{del}"
}
}
F1 핫키를 누르면 대화상자를 통해 사용자에게 삭제 여부를 질문한다.
사용자가 예 버튼을 누르면 del키를 누르고 아니오 버튼을 누르면 아무 것도 하지 않는다. 굉장히 간단한 구문이며 쉽다고 느껴지겠지만 프리포맷이 아니어서 까다로운 형식에 일일이 맞춰야 한다. 조건에 걸리는 명령은 { } 블록 안에 작성하는게 보통이지만 명령이 하나 뿐이라면 블록을 생략할 수 있다.
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes")
Send "{del}"
{ } 블록이 없어지니 코드가 두 줄이나 더 짧아진다. 그러나 아무리 간단한 명령이라도 조건과 명령을 한 줄에 쓰는 것은 안된다. 블록을 감싸도 마찬가지이다. C나 자바에 익숙한 개발자는 이게 안된다는 거에 황당해한다.
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes") Send "{del}"
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes") { Send "{del}" }
이런 규칙을 일일이 신경쓰고 싶지 않다면 명령이 하나 뿐이더라도 무조건 블록을 감싸는 습관을 들이는 것이 좋다. 원한다면 여는 괄호 {는 조건문 다음에 써도 상관 없다. 이런 스타일을 OTB(One True Brace) 또는 K&R 방식이라고 한다.
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes") {
Send "{del}"
}
되는게 당연한거라고 생각하겠지만 더 살펴 보면 그렇지도 않다. 딱 이것만 된다. 닫는 괄호 }를 마지막 명령과 같은 줄에 쓰는건 또 안된다.
if (MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes") {
Send "{del}" }
조건은 괄호를 생략할 수 있다. 그러나 MsgBox 호출문은 리턴값을 사용하므로 괄호를 생략해서는 안된다. MsgBox와 여는 괄호 사이에 공백이 있어서도 안된다.
if MsgBox("선택 영역을 삭제할까요?", "질문", "YN") = "Yes" ; 가능
if MsgBox "선택 영역을 삭제할까요?", "질문", "YN" = "Yes" ; 에러
if MsgBox ("선택 영역을 삭제할까요?", "질문", "YN") = "Yes" ; 에러
이건 문법이 엄격한 것도 아니고 그냥 지저분한 것이다. 스크립트일 뿐이므로 정통 컴파일러에 비해 파서의 수준이 한참 떨어진다. 이후 버전에서는 이런 문제부터 시급히 해결해야 할 것으로 보인다. 문법이 이따구이므로 당분간은 섣불리 생략이나 형태를 변형하지 말고 예제 코드의 형식을 그대로 따르는 것이 안전하다.
if 다음의 else문은 조건이 만족하지 않을 때의 동작을 지정한다. if는 조건을 만족하지 않을시 명령을 무시하지만 if else는 조건에 따라 실행할 명령을 선택한다는 차이가 있다. 간단하게 예제 하나만 만들어 보자.
F1::
{
if A_ScreenWidth > 2000 {
MsgBox "모니터가 좋아 보입니다."
} else {
MsgBox "모니터에 돈 좀 쓰세요.", "돈 벌어서 뭐해?"
}
}
if else 구문을 한번 더 확장하면 if else if else가 되며 if else는 필요한만큼 얼마든지 나열하여 여러 조건을 순차적으로 점검할 수 있다. 이럴 때는 switch 문을 쓰는 것이 더 깔끔하다. 제어 변수의 값에 따라 각각의 처리를 지정할 수 있다.
F1::
{
color := "red"
switch color
{
case "red": MsgBox "빨간색"
case "blue": MsgBox "파란색"
case "green", "lime": MsgBox "초록색"
default :MsgBox "그 외의 색"
}
}
제어 변수값이 case와 일치하는 명령을 선택하여 실행한다. break는 필요 없으며 두 개 이상의 값은 콤마로 구분하여 나열한다. case에 만족하는 값이 없으면 default의 명령을 실행한다. 제어 변수를 지정하지 않고 case에서 조건을 개별적으로 판단할 수도 있다.
F1::
{
color := "red"
switch
{
case color = "red": MsgBox "빨간색"
case color = "blue": MsgBox "파란색"
case color = "green" or color = "lime": MsgBox "초록색"
default :MsgBox "그 외의 색"
}
}
스크립트는 if 문으로 조건을 판단하여 실행할 명령을 선택하는데 데스크탑에서의 조건은 주로 특정 윈도우의 존재 여부, 활성창이 누구인가, 마우스 아래의 창이 무엇인가 등이다. 앞에서 Run "Notepad"를 호출하여 메모장을 실행해 봤는데 이 명령은 메모장을 무조건 실행한다.
핫키를 누를 때마다 메모장이 계속 열리는데 사용자가 원하는 것은 이게 아닐 것이다. 이미 메모장이 열려 있다면 굳이 새로 열 필요 없이 실행중인 메모장을 활성화해 주기만 하면 된다. 이때 if 문을 사용한다.
F1::
{
if WinExist("ahk_class Notepad") {
WinActivate
} else {
Run "Notepad"
}
}
조건문에 WinExist 함수로 메모장의 존재 여부를 판별하고 그 결과에 따라 이미 실행중이면 WinActivate 함수로 활성화만 하고 그렇지 않다면 Run 명령으로 새 메모장을 실행한다. 이 코드가 더 정확하고 실용적이다.
loop
반복문은 똑같은 또는 유사한 작업을 일정 회수만큼 수행하는 명령이다. 오토핫키는 세 종류의 반복문을 제공하는데 loop를 빈번히 사용한다.
loop 횟수
{
반복할 명령
}
미리 지정한 횟수만큼 블록 내의 명령을 반복한다. 반복 횟수를 생략하면 루프 내에서 break 명령으로 탈출할 때까지 무한히 반복한다. 다음 스크립트는 <---> 를 5번 출력한다.
F1::
{
loop 5
{
Send "<---> "
}
}
Send "<---> " 명령을 다섯 번 쓴 것과는 달리 루프로 반복했으므로 회수를 조정하기 싶다. 5를 100으로 바꾸면 100번 반복한다. 완전히 똑같은 명령을 계속 반복하는 경우는 드물고 매 실행시마다 약간씩 다른 명령을 실행하는 경우가 더 많다. 이때 각 명령에 변화를 주기 위해 변수를 사용한다. 다음 루프는 목록의 앞쪽에 1부터 5까지 일련 번호를 붙인다.
F1::
{
cnt := 1
loop 5
{
Send "{home}" cnt ".{down}"
cnt++
}
}
cnt는 1로 초기화하고 루프를 다섯 번 반복하되 줄 처음으로 가 cnt의 값과 .을 찍고 다음 줄로 내려 간다. 성적순으로 학생을 다섯명 나열해 놓았을 때 이 루프는 앞에 석차를 붙인다. 학생 수만큼 루프를 돌면 전체에 대해 번호를 붙인다.
|
철수 영희 순희 동호 기훈 |
1.철수 2.영희 3.순희 4.동호 5.기훈 |
cnt의 초기값은 첫 번호이고 증가값은 증감분이다. 이 두 값을 조정하면 10부터 12, 14, 16, 18로 번호를 매길 수도 있다. 1부터 순서대로 증가하는 값이라면 A_Index 내장 변수를 활용하는 것이 간편하다.
F1::
{
loop 5
{
Send "{home}" A_Index ".{down}"
}
}
A_index는 1부터 시작해 반복할 때마다 자동으로 1씩 증가한다. 루프의 명령을 몇 번째 실행하고 있는지를 기억하는데 오토핫키가 매 반복시마다 값을 갱신하므로 편리하게 사용할 수 있다. 항상 1씩 증가하는데 만약 루프 내에서는 2씩 증가하는 값이 필요하다면 A_Index * 2를 사용하면 된다.
루프 중간에 빠져 나올 때는 break 명령을 사용한다. 특정 회수만큼 미리 정해 놓고 반복하는 것이 아니라 일정 조건이 될 때까지 반복하고 싶다면 회수를 밝히지 않고 무한히 반복되도록 해 놓고 if 문으로 조건을 평가하여 빠지면 된다.
F1::
{
loop
{
Send "타잔이 " (A_Index * 10) "원짜리 팬티를 입고 " (A_Index * 10 + 10) "원짜리 칼을 차고 노래를 한다. 아아아~~`n"
if (MsgBox("계속 하시겠습니까?", "질문", "YN") = "No")
{
break
}
}
}
사용자가 언제 No 버튼을 누를지 미리 알 수 없으므로 무한 루프를 구성하고 응답에 따라 루프를 빠져 나와야 한다. 이중 루프를 탈출할 때는 break 2식으로 탈출할 루프의 개수를 적는다. continue는 현재 반복을 중지하고 다음 반복으로 넘어간다. 무한 루프나 중첩 루프도 일반 프로그래밍에서와 같다. 다음 스크립트는 구구단을 출력한다.
F1::
{
dan := 2
loop 8
{
hang := 1
loop 9
{
Send dan " * " hang " = " dan * hang "`n"
hang++
}
dan++
Send "`n"
}
}
1단은 없으므로 2단~8단까지 8번 반복하고 각 단에 대해 1~9행까지 반복한다. hang은 1부터 1씩 증가하므로 굳이 변수를 쓸 필요 없이 A_Index 내장 변수를 사용해도 된다. 대량의 문자열이지만 반복문을 사용하면 한방에 만들어 낼 수 있다.
for
for 반복문은 컬렉션의 요소를 순환하는 반복문이다. 컬렉션의 요소를 순서대로 변수에 하나씩 대입하여 명령을 실행하고 블록 내부에서 변수값을 통해 요소값을 읽는다. 다른 언어의 foreach에 해당하는 반복문이다.
for 변수 in 컬렉션
{
반복할 명령
}
컬렉션이 어떤 요소로 구성되는가에 따라 리턴할 변수의 종류와 개수가 결정되는데 객체는 최대 19개의 값까지 한꺼번에 리턴할 수 있다. 배열인 경우는 배열 요소를 한번에 하나씩 리턴하며 맵은 키와 값의 쌍을 리턴다. 결국 for 반복을 통해 배열 요소를 하나씩 순서대로 읽는 것이다.
F1::
{
city := ["서울", "대전", "대구", "부산"]
song := ""
for c in city
{
song .= c . " 찍고 "
}
MsgBox song
}
city는 문자열 배열이며 이 배열을 순회하며 도시를 c 변수에 하나씩 꺼내 song 문자열에 누적했다. for가 배열 요소를 읽어 주므로 블록에서는 변수값만 읽으면 된다.
이런 작업은 loop로도 할 수 있다. 배열의 길이는 Length 속성으로 조사하며 요소는 [ ] 연산자로 읽는다.
F1::
{
city := ["서울", "대전", "대구", "부산"]
song := ""
loop city.Length
{
song .= city[A_Index] . " 찍고 "
}
MsgBox song
}
가능은 하지만 개수만큼 돌아야 하고 일일이 요소를 읽어야 하므로 불편하다. 스크립트에서 배열이나 컬렉션을 쓸 일이 그리 흔하지 않아 for문을 쓸 일이 많지는 않다.
while
while 명령은 계속할 조건을 정해 놓고 매 반복마다 조건이 만족하는지 점검하여 참인 동안 명령을 반복한다.
while 조건
{
반복할 명령
}
반복 회수가 미리 정해지지 않은 경우에도 사용할 수 있으며 명령 내부에서 조건의 진위 여부를 변경하는 구문이 포함되어 있어야 한다. 다음 스크립트는 1~100까지 정수의 합계를 구한다.
F1::
{
sum := 0
num := 1
while num <= 100
{
sum += num
num++
}
MsgBox sum
}
while 문은 처음부터 조건이 거짓이면 한번도 실행하지 않을 수 있으며 이때 실행할 명령을 else 절에 따로 기술할 수 있다. 반복문끼리는 대체성이 있어 while 문으로 작성한 코드는 loop로도 작성할 수 있다.
F1::
{
sum := 0
loop 100
{
sum += A_Index
}
MsgBox sum
}
더해지는 값이 1씩 증가하므로 이 방법이 훨씬 간편하다. 회수가 고정적인가, 조건이 중간에 변하는가, 최소 1번은 실행해야 하는가 등의 기준에 따라 적절한 반복문을 사용하면 된다.
함수
함수는 반복되는 작업을 형식에 맞게 미리 정의해 놓고 재사용하여 반복을 방지하는 코드 블록이다. Send, MsgBox 등은 오토핫키가 제공하는 함수이며 사용자가 직접 함수를 정의하여 사용할 수도 있다. 함수를 선언하는 형식은 다음과 같다.
함수명(인수목록)
{
본체
}
리턴값이 있다면 본체에서 return 명령으로 값을 반환한다. 두 정수를 더하는 간단한 함수를 만들어 보자.
Add(a, b)
{
return a + b
}
F1::
{
MsgBox Add(2, 3)
}
함수를 미리 정의해 두고 핫키나 자동 실행 스레드에서 호출한다. Add는 형식 인수 a, b를 받아 두 값의 합을 계산하여 리턴하는 역할을 한다. 호출원에서는 덧셈 연산을 할 필요 없이 Add 함수와 함께 더할 값을 인수로 전달하면 된다. Add(2, 3)은 5를 리턴한다. 함수를 단독으로 호출할 때는 괄호를 생략할 수 있으나 리턴을 받거나 다른 함수의 인수열에서 호출할 때는 괄호를 생략할 수 없다.
인수에 기본값을 지정할 때는 인수 목록에서 :=로 초기값을 대입하며 호출시 이 인수는 생략할 수 있다. 디폴트 인수는 뒤쪽부터 차례대로 지정해야 하며 중간에는 올 수 없다. 한 인수가 디폴트값을 가지고 있으면 그 뒤쪽의 인수도 모두 디폴트값을 가져야 한다. 다음 Sum 함수는 from ~ to까지의 합계를 구해 리턴하되 각각 1과 100의 디폴트값이 지정되어 있다.
Sum(from := 1, to := 100)
{
sum := 0
f := from
loop
{
sum += f
if (f = to)
break
f++
}
return sum
}
F1::
{
MsgBox Sum()
MsgBox Sum(50)
MsgBox Sum(10, 20)
MsgBox Sum(, 10)
}
인수 없이 Sum()이라고 호출하면 디폴트 인수가 적용되어 1~100까지의 합계를 구하고 시작값 50만 지정하면 50~100까지의 합계를 구한다. 10, 20으로 실인수를 분명히 전달하면 디폴트 인수를 무시하고 호출원이 전달한 인수를 사용한다.
앞쪽 인수만 생략하고 뒤쪽 인수만 지정할 때는 빈 콤마를 찍어 둔다. (, 10) 인수열은 from은 디폴트인 1을 적용하고 to는 호출원이 전달한 100을 적용한다. 메시지 박스의 타이틀만 생략하고 싶다면 MsgBox "전달내용",,"YN' 식으로 중간 인수만 생략하면 된다.
호출원의 실인수는 그 값만 형식인수로 전달한다. 실인수의 사본을 전달받은 것이므로 함수 내부에서 형식인수를 아무리 바꿔도 실인수의 값은 바뀌지 않는다. 함수가 실인수를 직접 조작하려면 값이 아닌 참조를 전달해야 하며 이때는 &연산자를 붙인다. 참조호출의 전형적인 예는 두 값을 교한하는 것이다.
Swap(&a, &b)
{
t := a
a := b
b := t
}
F1::
{
a := 4
b := 5
Swap(&a, &b)
MsgBox "a = " a ", b = " b
}
함수는 한번에 하나의 값만 리턴할 수 있지만 참조호출을 사용하면 두 개 이상의 값을 리턴할 수도 있다. x, y 좌표나 색상값 등 여러 값으로 구성된 정보를 리턴할 때 참조호출을 종종 사용한다. 아니면 배열이나 객체를 통해 값을 묶어 반환하는 방법을 쓰기도 한다.
가변 인수를 전달할 때는 마지막 인수에 * 기호를 붙인다. 가변 인수 자리에는 임의 개수의 실인수를 전달할 수 있으며 함수는 배열의 형태로 가변 인수를 전달받는다. 본체에서는 for 문으로 순회하여 가변 인수를 하나씩 꺼내 사용한다.
Total(num*)
{
sum := 0
for n in num
{
sum += n
}
MsgBox sum
}
F1::
{
Total 1, 2, 3
Total 4, 5, 6, 7
}
Total 함수는 임의 개수의 정수를 전달받아 이 정수들의 합을 구해 리턴한다. 3개든 4개든 얼마든지 많은 정수를 인수로 전달할 수 있다.
변수의 범위
변수는 선언 위치에 따라 지역 변수와 전역 변수가 있다. 전역 변수는 함수 바깥에 선언하며 핫키, 핫스트링, 함수 어디에서나 참조할 수 있다. 이에 비해 함수 내부에서 선언하는 지역 변수는 이 함수에서만 읽을 수 있으며 외부에서는 읽을 수 없다. 함수 내의 { } 블록에서만 사용하는 블록범위 변수는 지원하지 않는다. 다음 예제로 테스트해 보자.
glo := 3
f1()
{
loc := 4
MsgBox "glo = " glo ", loc = " loc
}
f2()
{
MsgBox "glo = " glo
; MsgBox loc
}
f3()
{
glo := 9
}
F1::f1()
F2::f2()
F3::f3()
전역 변수로 선언한 glo는 f1, f2 함수에서 모두 읽을 수 있다. f1에서 선언한 loc 지역 변수는 f1 안에서만 읽을 수 있고 f2에서는 읽을 수 없다. 여기까지는 일반적인 언어와 같으므로 쉽게 이해할 수 있다. 그러나 f3의 동작은 비상식적인데 여기서 glo의 값을 변경했지만 전역 변수의 값은 전혀 바뀌지 않는다. F3 핫키를 누른 후 F1을 눌러 보자.
이렇게 되는 이유는 f3에서 사용한 glo는 이름만 전역 변수와 같을 뿐 f3 내부의 지역 변수이기 때문이다. 전역과 지역의 이름 충돌이 발생하면 함수 내부에서는 지역에 더 우선권을 주도록 되어 있다. f3의 glo가 새로 선언하는 지역 변수가 아니라 전역 변수라면 이 변수에 값을 대입하기 전에 global 선언을 먼저 해야 한다.
f3()
{
global glo
glo := 9
}
이렇게 수정하면 f3 함수 내부에서 glo 지역 변수를 따로 만들지 않고 전역 변수 glo를 참조한다. 이제 F3 핫키를 누른 후 F1을 누르면 glo 전역 변수는 9가 되어 있을 것이다. 만약 전역 변수 glo가 없다면 이때는 전역 변수를 직접 생성해 준다.
정적 변수는 변수 선언문 앞에 static 키워드를 붙여 선언한다. 함수 내부에서 선언하며 함수 내부에서만 사용할 수 있다는 면에서 지역 변수와 같지만 함수 호출간에도 값을 유지한다는 면에서는 전역 변수와 유사하다. 함수 혼자 쓰지만 다음 호출시에도 값이 남아 있어야 한다면 static으로 선언한다. 다음 스크립트는 자신의 호출 회수를 정적 변수에 저장한다.
F1::
{
static cnt := 1
MsgBox cnt . "번째 호출했습니다."
cnt++
}
F1을 누를 때마다 자신이 몇 번째 호출되었는지 알려 준다. 핫키를 누를 때마다 블록은 계속 새로 시작하지만 회수를 잘 유지하고 있다. 함수와 관련된 값이며 외부에서 이 값을 쓸 일은 없으므로 함수 내부에 있어야 하고 함수 호출간에도 값을 계속 유지해야 한다. 이럴 때 사용하는게 정적 변수이다.
오토핫키는 지역 함수도 지원한다. 함수 내부에 함수를 또 만들고 외부 함수에서만 사용하는 함수이다. 이때 내부 함수가 외부 함수의 변수를 캡처하는 클로저의 개념도 있다. 언어의 기능이 많아서 나쁠 것은 없겠지만 솔직히 이 기능은 스크립트 수준에서는 쓸 일이 거의 없다. C/C++도 지원하지 않는 기능이며 지원하는 언어도 사용을 자재하는 난해한 개념이다.
이상으로 오토핫키 강좌를 마칩니다. 실용적으로 사용할 수 있는 수준까지는 골고루 다루었으나 일부 고급 문법과 내부적인 모드는 다루지 못했습니다. GUI 환경에서 윈도우나 컨트롤까지 제어하는 실습 예제까지 만들어 보고 싶었으나 적절한 활용예를 발굴하는데 시간이 걸려 이번 강좌에서는 제외했습니다. 다음에 업데이트할 기회가 있다면 더 많은 내용과 실용적인 예제를 추가해 보겠습니다.