6.변수

선언

오토핫키의 기본적인 사용법은 모두 알아 보았다. 이제 남은 건 스크립트의 본체를 작성하는 것이다. 예제에서는 Send로 키를 보내거나 MsgBox로 호출되었음만 간단히 확인해 봤는데 스크립트를 정밀하게 작성하면 더 실용적인 처리를 할 수 있다. 오토핫키는 단순한 유틸리티가 아니라 프로그래밍 언어이다. 여기서부터는 코딩의 영역이며 C, 자바, C/C++ 등 여타의 전통적인 언어와 크게 다르지 않다.

코딩을 배워야 한다는 얘긴데 오토핫키의 문법은 프로그래밍 입문용으로 전혀 적합하지 않다. 스크립트로 변수, 함수, 조건문을 배우는 것은 비효율적이며 개념을 잡기 어렵다. 시간이 좀 걸리더라도 파이썬이나 자바스크립트 등의 간단한 언어로 문법은 따로 배워야 한다. 여기서는 코딩의 기본은 안다고 가정하고 문법을 요약적으로 정리만 한다.

변수는 값을 임시적으로 저장하는 기억 장소이다. 선언할 필요없이 필요할 때 언제든지 사용할 수 있으며 타입은 따로 없고 초기화 또는 대입되는 값으로 자동 결정한다. 인터프리터인만큼 변수를 사용하기는 간편하지만 형식성은 떨어진다. 변수를 선언하는 기본 형식은 다음과 같다.

변수명 := 초기값

:=로 대입하는 즉시 초기화되며 다른 값을 대입하지 않는 한 이 값을 계속 유지한다. 초기화하지 않은 변수를 사용하면 에러 처리되므로 초기값을 생략해서는 안된다. 변수를 선언하고 사용하려면 최소한 두 줄을 되어야 하므로 { } 블록을 구성해야 한다.

F1::

{

a := 23

a := a + 1

MsgBox("a는 " a "입니다.")

}

a를 23으로 초기화하는 즉시 a 변수가 생성되고 정수 23의 값을 가진다. C, 자바 개발자는 세미콜론을 습관적으로 붙여 a := 23; 식으로 적는 경우가 많은데 오토핫키는 명령어 끝에 세미콜론을 사용하지 않으므로 유의하자. 숫자이므로 연산이 가능한데 1 더한 값을 a에 대입한 후 메시지 박스로 값을 확인했다. 당연히 24가 출력된다.

타입 구분이 엄격하지 않지만 리터럴에는 타입이 있다. 숫자형은 정수, 실수가 있는데 소수점이 있으면 실수이고 아니면 정수이다. 정수는 부호있는 64비트이며 음양으로 900경의 큰 값을 넉넉히 저장할 수 있어 일반적인 용도로 전혀 부족하지 않다. 숫자만 쓰면 10진수이고 0x 접두를 붙이면 16진수이다.

실수는 IEEE754 표준에 따른 64비트 포맷이며 C나 자바의 double 형과 같다. 고정 소수점 형태의 3.14로 표기할 수도 있고 314e-2 식의 공학적 표기법을 쓸 수도 있다. 타입 구분이 엄격하지 않아 중간에 이미 사용하던 변수를 다른 타입으로 자유롭게 바꿀 수도 있다.

F1::

{

a := 0x23

MsgBox("a는 " a "입니다.")

a := 3.14159265358979

MsgBox("a는 " a "입니다.")

}

0x23은 십진수로는 35이다. 처음에 정수값을 저장하다가 실수를 대입하면 실수 변수로 바뀐다. 숫자형과 문자열, 진위형으로도 자유롭게 바꿔쓸 수 있다. 그러나 변수의 용도를 바꿔가며 쓰는 것은 바람직하지 않으므로 처음부터 의미를 잘 정해 쓰는 것이 좋다.

진위형은 따로 없고 정수를 대신 사용한다. 0이면 거짓이고 그 외의 값이면 모두 참으로 평가한다. 문자열은 ""로 비어 있으면 거짓이고 내용이 있으면 참으로 평가한다. 참, 거짓에 대해 각각 true, false 키워드가 정의되어 있다.

문자열

문자열은 큰 따옴표나 작은 따옴표로 감싸 표현한다. 어떤 따옴표를 쓰든 상관 없으며 여는 따옴표와 닫는 따옴표가 같기만 하면 된다. 지금까지의 예제에서는 큰 따옴표를 주로 사용했는데 작은 따옴표로 감싸도 상관 없으며 오히셔 Shift를 누르지 않고 입력할 수 있어서 간편하다.

Send '^{v}'

따옴표안에 다른 따옴표를 표기할 때는 반대쪽 따옴표로 문자열을 감싼다. 큰 따옴표안에 작은 따옴표를 넣든가 반대로 할 수 있다.

MsgBox "선물을 받으면 '고맙습니다'라고 인사를 한다."

MsgBox '선물을 받으면 "고맙습니다"라고 인사를 한다.'

"선물을 받으면 "고맙습니다"라고 인사를 한다." 요렇게 표기하면 어디까지 문자열인지 판단할 수 없어 말이 안되며 로드중에 에러 처리해 버린다.

그렇다면 큰 따옴표와 작은 따옴표를 동시에 문자열에 넣으려면 어떻게 할까? 이때는 확장열을 사용한다. 확장열은 `로 시작하며 문자열내의 특수한 기호를 표현한다. 작은 따옴표 '가 아니라 1키 옆에 있는 `이며 BackTick 또는 어포스트로피라고 부르는 기호이다.

확장열	설명
`"	큰 따옴표
`'	작은 따옴표
``	백틱
`t	탭
`n	개행
`r	개행
`s	공백

확장열을 사용하면 문자열안에 모든 문자를 다 표기할 수 있고 여러 줄의 문장을 개행하여 넣을 수도 있다.

F1::MsgBox "큰 따옴표 `", 작은 따옴표 `' 확장열로 표기"

F2::MsgBox "안녕하세요.`n반갑습니다."

문자열은 사용자에게 결과를 출력하는 가장 직관적인 방법이다. 변수값을 보여 줄 때도 문자열안에 포함하여 출력하는데 이때는 . 연산자를 사용한다.

F1::

{

name := "김상형"

age := 29

intro := "이름 : " . name . " ,나이 : " . age

MsgBox(intro)

}

문자열과 정수를 하나로 연결할 때 . 연산자로 변수를 나열하면 하나의 문자열로 합쳐준다. 연쇄적으로 사용할 수 있어 여러 개의 변수를 연결할 수 있다. 이름과 나이를 하나의 문자열로 조립하여 메시지 박스로 출력한다.

이때 . 연산자는 양쪽에 공백이 있어야 하며 붙여쓰면 안된다. 문자열과 변수를 중간 중간에 연결할 때는 .을 생략해도 공백으로 구분 가능하다. 다음 코드도 똑같이 동작한다.

intro := "이름 : " name " ,나이 : " age

앞에서 a 변수를 출력할 때 "a는 " a "입니다." 식으로 표기했었다. 굳이 . 연산자를 쓸 필요없어 보통 생략하지만 값 사이의 경계를 분명히 표기할 때는 .을 꼭 찍어야 한다. MsgBox "강의실 = " . 3 . -4는 세 값을 연결하여 '강의실 = 3-4'를 출력하는데 점을 생략하고 MsgBox "강의실 = " 3 -4로 적으면 3 -4가 연산되어 -1이 되어 버린다.

연결 연산자로 변수를 나열하는 것은 쉽지만 문자열과 변수가 섞여 있으면 읽기 어렵고 편집할 때도 헷갈린다. 더 편리하고 공식적인 방법은 Format 함수로 서식을 넣어 조립하는 것이다. 문자열내에 {1}, {2} 식으로 서식을 넣어 두면 이 자리에 뒤쪽의 인수값이 들어간다.

intro := Format("이름 : {1}, 나이 : {2}", name, age)

서식 조립은 C나 자바에도 있는 방법인데 서식이 {0}부터 시작하는게 아니라 {1}부터 시작한다는 차이가 있다. 전통적인 언어는 수를 셀 때 항상 0부터 시작(Zero Base)하지만 오토핫키는 1부터 시작(One Base)한다.

내장 변수

내장 변수는 오토핫키가 정보를 제공하기 위해 미리 정의해 놓은 변수이다. A_로 시작하며 정해진 이름으로 읽기만 하면 정보를 조사해 준다. 굉장히 많은데 자주 쓰는 몇 가지만 정리했다. 전체 목록은 도움말을 참고하자.

변수	설명
A_Now	현재 날짜와 시간
A_TickCount	부팅후 경과 시간
A_ScriptName	현재 실행중인 스크립트
A_ScreenWidth, A_ScreenHeight	모니터 크기
A_OSVersion	운영체제 버전
A_ProgramFiles	프로그램 저장 경로
A_Temp	임시 디렉토리 경로
A_Clipboard	클립보드 객체
A_Index	루프 실행 순서값. 1부터 시작

어떤 값을 가지는지 찍어 보자. 문자열로 조립하여 메시지 박스로 열어 보면 된다.

F1::

{

MsgBox("현재 시간 " A_Now)

MsgBox("스크립트 " A_ScriptName)

MsgBox("모니터 크기 " A_ScreenWidth " * " A_ScreenHeight)

}

세 개의 정보를 문자열 하나로 조립하여 메시지 박스로 출력한다.

내장 변수의 값은 미리 정해진 것이 아니라 요청할 때 실시간으로 조사한다. 현재 시간은 항상 바뀌는 정보이며 운영체제의 버전이나 화면 크기도 시스템마다 천차만별일 뿐만 아니라 실행중에도 바뀔 수 있다. 별도의 조사 함수를 쓸 필요 없이 변수만 읽으면 되니 사용하기 편하다.

프로그램은 자신이 실행되는 환경을 가정하지 말고 항상 실시간으로 조사해서 사용해야 한다. 예를 들어 임시 파일을 생성할 필요가 있을 때 C:\Temp로 가정하면 이 폴더가 항상 있다고 보장할 수 없다. A_Temp 내장 변수를 읽어 폴더를 조사해야 안전하다. 다음 스크립트는 클립보드안에 저장된 내용을 보여 준다.

F1::MsgBox A_Clipboard

A_Clipboard의 내용을 읽기만 하면 붙여 넣어 보지 않아도 어떤 문자열이 저장되어 있는지 간편하게 확인할 수 있다.

굉장히 긴 문서가 복사되어 있을 수도 있는데 줄 별로 분해해서 살펴 보거나 딱 원하는 정보만 골라 가져오는 것도 가능하다.

오브젝트

단일 변수는 하나의 값만 저장하는데 비해 객체는 여러 개의 값을 묶어서 저장한다. 또한 정보를 저장하는 속성과 동작을 처리하는 메서드까지 겸비하여 변수보다 활용성이 높다. 오토핫키는 완전히 객체지향적이지는 않지만 객체를 활용하는 문법은 다 구비하고 있다.

배열은 Array 클래스로 표현하며 여러 개의 값을 연속된 메모리에 저장하는 자료 구조이다. 이름은 배열이지만 중간에 첨삭이 가능한 동적 배열이며 일반적인 의미로는 리스트라고 할 수 있다. [ ] 괄호안에 요소를 나열하여 초기화 하거나 Array() 생성자 호출문 안에 요소를 나열한다. 주요 속성과 메서드는 도표로 정리한다.

속성, 메서드	설명
Length	요소의 개수
[n]	n번째 요소 참조
InsertAt(위치, 값)	요소 삽입
Push(값)	값 추가
RemoveAt(위치)	요소 삭제
Pop()	마지막 요소 삭제

어느 언어에나 있는 아주 일반적인 자료 구조이여서 사용하기는 무척 쉽다. 다만 스크립트의 특성상 차이가 있는데 배열의 요소가 꼭 같은 타입일 필요는 없고 첨자는 항상 1부터 시작한다.

F1::

{

arGeneral := ['이순신', '김유신', '강감찬']

;arGeneral := Array('이순신', '김유신', '강감찬')

arGeneral.InsertAt(3, '을지문덕')

arGeneral.RemoveAt(2)

gen := ""

for (g in arGeneral)

{

gen .= g . ", "

}

MsgBox gen

}

세 명의 장군을 가지는 크기 3의 배열을 선언했다. 3번째 위치에 을지문덕을 삽입하고 2번째 위치의 장군을 삭제했다. 배열을 순회할 때는 다음 절에서 알아볼 for문을 사용하는데 여기서는 일단 덤프만 해 보자. 김유신이 을지문덕으로 대체되었다.

맵은 키와 값의 쌍을 가지는 자료 구조이며 연관 배열이라고도 하고 딕셔너리라고도 부른다. 키로부터 값을 빠르게 찾을 수 있어 검색 속도가 월등히 빠르다. 생성자의 인수로 두 개씩 짝을 이루어 키와 값을 순서대로 전달하여 초기화한다. 요소를 참조할 때는 [ ] 괄호안에 키를 전달하여 읽고 쓴다. 요소를 쓸 때 이미 있으면 변경하고 없으면 추가한다. 요소를 삭제할 때는 Delete 메서드를 사용한다.

F1::

{

money := Map('김상형', 1000, '김잠숙', 500, '문종민', 29)

money['권성직'] := 80

MsgBox "김상형의 후원금은 " money['김상형']

}

money는 후원금의 목록이며 사람 이름이 키이고 후원 금액이 값이다. 수천만명의 정보가 저장되어 있더라도 이름으로부터 후원금을 빠르게 검색할 수 있다.

배열과 맵은 자료의 집합에 특화된 일종의 컬렉션이다. 더 일반적인 객체는 { } 괄호안에 속성과 값의 쌍으로 초기화하여 실세계의 사물을 표현한다. C의 구조체에 해당한다. 속성을 읽을 때는 . 연산자 다음에 속성명을 적는다. 맵의 키와는 달리 속성명이 일종의 명칭이라는 점이 다르다.

F1::

{

human := {name:'김상형', age:29, height:182}

MsgBox human.name "의 키는 " human.height

}

사람 객체를 하나 생성하고 이름과 키를 읽어 보았다. 객체.속성의 형식으로 참조할 수 있어 편리하며 속성명을 잘못 적으면 로드시에 오타임을 알 수 있어 안전하다.

오토핫키는 클래스를 정의하는 문법도 제공하며 나름 꽤 잘 정리되어 있다. 메서드도 포함할 수 있고 액세서를 통한 안전한 정보 관리, 상속으로 계층을 구성하는 기능까지 웬만한 언어가 제공하는 기능은 모두 갖추었다.

그러나 정보 은폐와 상속에 의한 다형성 구현 등의 고급 문법은 빠져 있다. 쓸만하게는 되어 있지만 솔직히 스크립트가 이런 문법까지 제공할 필요가 있나 싶은 생각이 들어 강좌에는 제외했다. 객체 지향은 원래 어려운 주제인데 정통 언어로 제대로 배우는게 더 낫다.

연산자

연산자는 변수의 값을 조작하는 수단이다. 웬만한 언어에 있는 기본 연산자는 모두 제공하며 오토핫키 고유의 연산자도 있다.

연산자	설명
:=	대입
.=	연결
+ - * / //	가감승제, 나머지
++ --	증감 연산자. 전위, 후위 표기 모두 가능
**	거듭승
+= -= *= /= //=	복합 대입
< <= > >=	비교 연산자
= != == !==	상등 연산자. =은 대소문자 구분, ==은 무시
&& || ! and or not	논리 연산자
<< >> >>>	쉬프트
& ^ |	비트 연산자
~=	정규식 비교
is	타입 비교
? :	삼항 조건 연산자
??	초기화되지 않았을 때의 대체값 지정

변수끼리 연결하는 .= 연산자가 특이하다. 문자열 변수와 함께 쓰면 뒤쪽에 다른 변수의 값을 계속 덧붙여 하나의 변수에 정보를 모은다.

F1::

{

city := "서울"

city .= "대전"

city .= "대구"

city .= "부산"

MsgBox(city)

}

최초 서울로 초기화하고 이후 대전, 대구, 부산을 차례대로 덧붙인다. city .= "대전"은 city := city . "대전"과 같되 피연산자가 한번만 나와 더 쓰기 편하다. 문자열 뿐만 아니라 정수나 실수, 심지어 변수까지도 얼마든지 덧붙일 수 있다.

C나 자바를 해 본 사람이라면 특별한 주의사항없이 쓰던대로 사용하면 된다. 거듭제곱까지 함수가 아닌 연산자로 제공하는 편리함이 있는 반면 비트, 쉬프트 연산자는 솔직히 스크립트 수준에는 별로 어울리지 않는 고급 연산자이기도 하다.

연산 순위와 결합 방향의 개념도 있어 덧셈보다는 곱셈을 먼저 계산한다. 어떤 언어에서나 연산 순위에는 충분히 주의를 기울여야 하는데 순위를 강제로 변경하거나 우선 순위에 자신이 없으면 괄호로 감싸 순위를 분명히 지정하는 것이 좋다.