5.기본 함수

MsgBox

오토핫키는 기본적인 동작을 함수로 제공하며 키입력 처리에 필요한 대부분의 기능을 함수로 정의해 두었다. 함수는 특정한 동작을 수행하는 실행 단위이며 명령이라고 생각하면 된다. 인수로 동작에 필요한 정보를 전달하면 이 정보를 바탕으로 약속한 동작을 수행한다.

가장 쉬운 명령은 대화상자를 열어 메시지를 보여 주는 MsgBox이다. 사용자에게 보고할 내용이나 질문할 사항이 있을 때 대화상자를 통해 보여 주고 입력 받는다. 함수를 호출하는 기본 형식을 원형이라고 하며 도움말에 기록되어 있다. 함수에 대한 상세한 정보는 항상 도움말을 참고해야 한다.

MsgBox [Text, Title, Options]

Result := MsgBox([Text, Title, Options])

원형에서 [ ] 괄호안은 옵션이라는 뜻이며 전달할 수도 있고 아닐 수도 있다. MsgBox 함수는 세 개의 인수를 받는데 Text는 전달할 내용, Title은 타이틀 바의 제목, Options는 버튼 종류나 아이콘을 지정한다. 내용까지 생략하면 "Press OK to continue."라는 짧은 메시지를 보여 주며 내용전달보다는 실행을 잠시 중단하는 효과만 있다.

전달사항만 보여줄 때는 단순히 호출만 하면 되고 괄호도 생략할 수 있다. 반면 질문을 할 때는 리턴값을 대입받아야 하며 괄호를 생략할 수 없다. 공식 문서는 뭔가 복잡해 보이는데 이후부터는 정확도를 약간 희생하더라도 간략하게 표시하도록 한다.

MsgBox "메시지", "제목", "옵션"

MsgBox 다음에 전달할 내용을 문자열로 적는다. 뒷쪽의 인수는 생략시 무난한 디폴트값이 적용되므로 변경할 필요가 있을 때만 전달하면 된다. 다음 코드를 작성해 보자.

F1::MsgBox "F1을 눌렀습니다."

F2::MsgBox "F2 키를 눌렀습니다.", "알립니다"

한글도 물론 사용할 수 있으며 길어도 상관없다. 함수를 호출할 때는 원칙적으로 인수를 괄호로 감싸야 한다.

F1::MsgBox("F1을 눌렀습니다.")

이게 원칙이나 번거롭기 때문에 괄호 생략을 허용한다. 어차피 한 줄에 한 명령을 작성하므로 괄호를 생략해도 해석에는 별 문제가 없다. 인수를 모두 생략할 때도 빈 괄호를 칠 필요없이 MsgBox라고만 적으면 되니 간편하기는 하다.

v2에서는 공식적으로 괄호를 칠 것을 권장하지만 귀찮은걸 싫어하는 건 인류의 공통 습성이라 공식 도움말의 예제조차도 괄호없이 되어 있는 경우가 많다. 사실 앞뒤로 괄호와 따옴표까지 이중으로 감싸기는 번거롭다. 스크립트 실행 후 F1, F2를 누르면 메시지 박스가 나타난다.

전달할 내용이 메시지 박스 중앙에 표시된다. 타이틀을 지정하지 않으면 스크립트의 이름을 표시하고 버튼은 "확인" 하나만 나타난다. 메시지 박스가 떠 있는 동안 실행은 잠시 중단되며 확인 버튼을 눌러야 다음 명령으로 넘어간다.

호출만 하면 결과를 바로 볼 수 있어 학습 및 개발용으로 유용하다. 어떤 키가 눌러졌는지 쉽게 확인할 수 있고 스크립트의 현재 상황을 상세히 찍어 볼 수 있다. 그러나 사용자가 대화상자를 닫기까지 흐름을 멈추는 문제가 있어 실제 업무에서는 사용을 자재하는 것이 좋다.

옵션은 버튼의 종류를 지정하는데 디폴트는 OK이며 정보만 전달한다. 질문이나 다음 동작에 대한 선택을 보여 주려면 버튼의 종류를 지정하는 옵션을 전달한다. 옵션명에 버튼 종류가 잘 설명되어 있지만 너무 길어 입력하기 불편하니 짧은 축약형을 쓰는 것이 좋다.

옵션	줄임말	버튼 종류
OK	0	OK
OKCancel	O/C or OC	OK, Cancel
AbortRetryIgnore	A/R/I or ARI	Abort, Retry, Ignore
YesNoCancel	Y/N/C or YNC	Yes, No, Cancel
YesNo	Y/N or YN	Yes, No
RetryCancel	R/C or RC	Retry, Cancel
CancelTryAgainContinue	C/T/C or CTC	Cancel, Try Again, Continue

옵션에 Iconl, Icon?, Icon!, Iconi를 추가하면 메시지 옆에 아이콘을 표시한다. 버튼 종류와 아이콘을 같이 지정할 때는 옵션을 공백으로 구분하여 "YN Icon?" 식으로 전달한다. 질문을 할 때는 YN이나 YNC 옵션으로 버튼을 배치하고 사용자의 응답을 리턴값으로 받는다. 다음 스크립트를 작성해 보자.

F1::reply := MsgBox("밥 먹었어요?", "질문", "YN")

F2::MsgBox "에러 발생", "아이쿠", "IconX"

F1을 누르면 밥 먹었는지 물어 보되 응답을 받아야 하니 Yes, No 버튼을 배치한다. F2는 에러 메시지를 보여 주되 주의를 환기시키는 아이콘도 같이 표시한다.

사용자의 응답은 reply 변수에 대입받으며 이후 조건문으로 응답에 따라 다른 처리를 수행할 수 있다. 리턴을 받을 때는 인수 목록을 반드시 괄호로 감싸야 한다. 다음과 같이 괄호를 생략하면 함수 호출부와 대입부가 명확히 구분되지 않아 에러로 처리한다.

F1::reply := MsgBox "밥 먹었어요?", "질문", "YN"

리턴을 받거나 함수를 중첩해서 호출할 때는 괄호를 분명히 싸야 한다. 차라리 무조건 괄호를 싸도록 규칙을 정했으면 더 좋을텐데 편의성 때문에 생략을 허용하다 보니 초보자는 어렵게 느껴지고 오토핫키의 난이도를 높인다. 사실, 이 문제는 파서의 수준 문제인데 다음 구문도 에러이다.

F1::reply := MsgBox ("밥 먹었어요?", "질문", "YN")

아무 이상 없는 거 같지만 함수명과 ( 사이에 공백이 있으면 안된다는 규칙이 있다. 반드시 MsgBox( 로 붙여 써야 한다. 이런 이상한 규칙이 있는 이유는 공백이 연결 연산자로도 사용되기 때문이지만 탁 까 놓고 얘기해서 그냥 언어의 수준이 떨어지는 것이다. 아무래도 스크립트가 C, 자바 수준의 형식성을 갖추기는 어렵다.

MsgBox는 메시지를 보여주거나 버튼으로 단순한 질문을 할 수는 있지만 문자열을 입력받을 수는 없다. 이때는 InputBox 함수를 사용한다.

변수 := InputBox(질문, 타이틀, 옵션)

사용자의 입력을 리턴받아야 하므로 대입문은 필수이며 따라서 괄호도 생략할 수 없다. 리턴받은 객체의 Value 속성에 사용자가 입력한 문자열이 있고 Result 속성에 사용자가 누른 버튼 이름이 있다. 다음 스크립트를 작성해 보자.

F1::

{

name := InputBox("이름을 입력하세요", "너 누구니?")

if (name.Result == "OK")

{

MsgBox "반갑습니다. " name.Value "님"

}

}

이름을 물어 보고 입력받은 이름을 메시지 박스로 다시 보여 준다. 입력중에 취소했으면 아무 것도 하지 않는다. 아직 배우지 않은 조건문을 사용했는데 다음에 알아 보기로 하자.

자동화된 스크립트는 실행만 하면 알아서 돌아가는게 보통이지만 활용성을 높이기 위해 시작 번호, 반복 회수, 대상 문서 등을 실행중에 사용자로부터 입력받아야 하는 경우가 있다. 이럴 때 대화상자를 사용한다.

Send

핫키는 사용자가 미리 지정해 놓은 키 입력을 활성 윈도우로 보내 동작을 수행한다. 이때 사용하는 함수가 Send이며 앞에서 이미 여러 번 사용해 보았다. 원형 자체는 무척 단순해서 보낼 내용을 따옴표안에 적기만 하면 된다.

Send "보낼 내용"

보낼 내용은 문자열이거나 키이되 키는 { } 괄호안에 적고 문자열과 조합키는 { } 괄호밖에 적는다. "{left}"라고 적으면 왼쪽 이동키를 의미하고 "left"는 left라는 단어를 의미한다. 다음 스크립트를 작성해 보자.

F1::Send "KoRea"

F2::Send "대한민국 Korea"

F3::Send "{F5}"

F1을 누르면 KoRea 문자열이 나타난다. K와 R이 대문자로 되어 있으며 이때 오토핫키는 Caps키의 상태까지 고려하여 Shift키를 적절히 눌러 준다. 그러나 한글 모드까지는 점검하지 않고 키를 순서대로 눌러줄 뿐이며 ㅏㅐㄲㄷㅁ로 입력된다. 세 번째 문자가 ㄱ이 아니라 ㄲ임을 유의하자.

한글은 키가 아닌 문자열 형태로 전송하도록 되어 있어 한영 모드에 영향을 받지 않는다. 뭔가 불완전한 모습인데 국제어까지 섬세하게 고려하여 만든게 아니다 보니 원하는대로 잘 동작하는지 테스트 해 보고 사용해야 한다. 항상 똑같은 문자열을 입력하려면 전송 모드(SendMode)라는 복잡한 것까지 동원해야 한다.

F3을 누르면 F5키를 입력한다. 문자열 F5가 아니라 F5키를 눌러 주는 것이다. 오토핫키는 이 키를 눌러만 줄 뿐이지 어떤 명령인지까지 관여하지는 않으며 프로그램마다 다르다. 메모장에서 F5를 누르면 현재 시간을 입력하고 웹브라우저에서 F5를 누르면 새로고침한다. 워드에서는 찾기/바꾸기 창이 열리며 어떤 프로그램은 아무 반응도 보이지 않는다.

단축키를 입력할 때는 Ctrl, Shift, Alt, Win키와 조합하며 기호 ^+!#을 키앞에 지정한다. ^{c}는 Ctrl+C이며 ^+{Esc}는 Ctrl+Shift+Esc이다. 조합키는 { }괄호의 밖에 있고 단축키는 { } 괄호안에 있음을 유의하자. 알파벳키와 조합할 때는 소문자로 적어야 해당키만 누르는 것이다. 다음 세 예를 보자.

F1::Send "^{f}"

F2::Send "^{F}"

F3::Send "^+{f}"

^{f}는 Ctrl+F이며 메모장이나 워드 등 대부분의 프로그램에서 찾기 대화상자를 띄워준다. 그러나 ^{F}는 F가 대문자이므로 Ctrl+Shift+F가 되며 이는 아예 다른 단축키이다. ^+{f}와 같은 의미이다. 워드에서는 글꼴 대화상자가 열리며 당근 텍스트 편집기에서는 파일 검색 대화상자가 열린다. 단축키 자체는 소문자로 적고 Ctrl, Shift 등의 조합키는 ^나 +기호로 지정하는 것이 바람직하다.

조합키를 의미하는 ^+!#를 문자 그대로 출력하고 싶다면 앞에 {Raw}를 붙인다. Send "{Raw}^_^"는 ^ 기호를 Ctrl키로 해석하지 않고 문자 그대로 해석하여 ^_^를 입력한다. 또는 ^ 기호만 { } 괄호로 감싸 Send "{^}_{^}"로 적어도 된다.

Send는 따옴표안의 문자와 키를 순서대로 보내므로 한번에 꼭 하나씩 적을 필요는 없다. 키든 문자든 나열해 놓기만 하면 앞에서부터 차례대로 활성 윈도우로 전송한다. 다음 스크립트를 보자.

F1::Send "{up}{end}"

F2::Send "{right}{right}{right}-"

F3::Send "{right 5}."

F1은 위로 한칸 이동하고 줄 끝으로 이동하므로 누를 때마다 윗줄 마지막으로 이동한다. Send "{up}" 과 Send "{end}"를 따로 적는 것과 같다. F2는 세칸씩 오른쪽으로 이동하며 - 문자를 하나씩 찍는다. 알파벳을 쭉 나열해 놓고 F2를 계속 누르면 매 세 글자마다 -을 삽입하는 식이다.

abc-def-ghi-jkl-mno-pqr-stu-vwx-yz

같은 키를 여러번 입력할 때는 { } 괄호안의 끝에 반복 숫자를 적는다. {right 5}는 오른쪽으로 다섯칸 이동한다는 뜻이며 F3을 누르면 매 다섯칸마다 .을 찍는다.

Send 명령 하나만 해도 입력과 이동을 자유롭게 할 수 있어 활용 용도가 무궁무진하다. 웹용 강좌를 써 놓고 웹 페이지로 만든다고 해 보자. 그냥 문자열만 나열하면 웹에서는 모두 한 줄로 붙어 나오므로 <br> 태그를 넣어 개행하든지 <p> 태그로 감싸 문단으로 만들어야 한다.

1.소개 2.설치 3.초기화 4.옵션

<p>1.소개</p> <p>2.설치</p> <p>3.초기화</p> <p>4.옵션</p>

이런 작업은 클립보드를 사용해도 노가다를 피하기 어렵다. 이럴 때 핫키를 사용하면 단 한방에 처리할 수 있다. 다음 핫키를 등록하고 태그로 감쌀 문장에서 F1만 열심히 누르면 된다.

F1::Send "{home}<p>{end}</p>{down}"

줄 처음으로 가 맨 앞에 <p>를 입력하고 줄 끝으로 가 </p>를 입력하여 한 줄을 문단화한다. 그리고 한칸 아래로 내려 다음 줄에 대한 처리를 연속으로 수행할 수 있도록 준비까지 해 준다.

한 줄에 대한 처리를 완벽하게 작성해 놓았으므로 F1을 누르는 족족 문단으로 바뀐다. 핫키의 위력을 어렴풋이 느낄 수 있는데 여기에 조건문이나 루프까지 동원하면 더 복잡하고 섬세한 편집도 한방에 수행할 수 있다.

Send는 { } 안의 키를 눌렀다 떼는 동작까지 같이 처리한다. 대개의 경우 키를 입력한다는 것은 눌렀다 떼는 것이지만 up, down을 지정하면 누르는 동작과 떼는 동작을 따로 지정할 수 있다.

F1::Send("{a down}{a up}")

a를 누른 후 떼라는 지시사항이며 그냥 {a}라고 적는 것과 같아 굳이 이럴 필요가 없다. 그러나 조합키는 누른 채로 어떤 동작을 할 수도 있는데 Ctrl키를 누른 채로 마우스를 클릭하는 등이 가능하다.

Run

Run 함수는 프로그램을 실행하거나 문서를 연다. 자주 사용하는 프로그램에 대해 핫키를 등록해 두면 간편하게 실행할 수 있다. 인수가 많지만 꼭 필요한 건 경로 하나 뿐이며 나머지 인수는 필요할 때만 지정하면 된다.

Run "경로", ["작업디렉토리", "옵션", &프로그램ID]

경로 자리에 실행할 프로그램이나 문서를 지정한다. 윈도우의 명령행에서 입력하는 명령과 비슷하다. 다음 스크립트를 작성해 보자.

F1::Run "notepad"

F2::Run "c:\Temp\ksh.jpg"

F3::Run "http://www.soen.kr"

F1을 누르면 메모장을 실행한다. 프로그램은 전체 경로를 지정하는 것이 원칙이지만 경로가 등록되어 있는 프로그램은 이름만 지정해도 바로 실행할 수 있다. 다음 두 구문이 원칙적으로 맞지만 메모장은 시스템이 제공하는 프로그램이어서 확장자까지 생략할 수 있다.

F1::Run "c:/windows/notepad.exe"

F1::Run "notepad.exe"

그냥 notepad라고 적어도 메모장인지 안다. 그러나 일반 프로그램은 경로까지 정확히 적어야 한다. 필요하다면 명령행 인수도 전달할 수 있는데 메모장에 인수를 전달하면 파일을 열어 준다. 만약 파일이 없으면 새로 만들어 준다.

F1::Run "notepad c:/temp/test.txt"

문서 파일을 지정하면 연결 프로그램을 실행하여 문서를 연다. 이미지 파일을 지정했으므로 사진 프로그램이 열리며 늠름한 군인 아저씨가 나타난다. 물론 이 파일이 존재해야 한다. 탐색기에서 이미지 파일을 더블클릭하는 것과 같다.

doc, hwp, mp3 등 잘 알려진 포맷을 핫키 하나로 바로 열 수 있어 편리하다. 자주 참고하는 사진이나 문서, 종종 듣고 싶은 음악을 등록해 두면 꽤나 실용적인 기능이다. 핫키 개수가 넉넉하지 않아 잘 안쓰는 키를 할당하는게 좋다. Ctrl+Alt+1에 이선희 노래, Ctrl+Alt+2에 조용필 노래를 등록해 놓으면 적당하다.

URL을 전달하면 웹 브라우저가 열리며 해당 사이트로 즉시 이동한다. 이 기능도 편리하지만 브라우저의 즐겨찾기가 워낙 잘 되어 있어 핫키까지나 할당할 필요는 없는 편이다. 어쨌거나 Run 함수는 실행 파일, 문서, 사이트까지 던지는 족족 열어 준다.

작업 디렉토리는 프로그램을 실행할 경로이며 생략시 스크립트가 있는 디렉토리에서 시작한다. 옵션은 초기 모드를 지정하는데 창 모드로 실행하는게 보통이지만 옵션에 Max, Min을 지정하여 최대화 상태나 최소화 상태로 시작할 수 있고 Hide로 지정하면 숨겨진 채로 실행한다.

Run은 프로그램을 기동한 후 즉시 리턴한다. 초기화에 시간이 좀 걸려 Run이 리턴한 직후에는 프로그램이 아직 완전히 실행되지 않은 상태이다. 이 상태에서는 방금 시작한 프로그램을 제어하거나 상호작용할 수 없다. 반면 RunWait 함수는 프로그램이 상호 동작을 할 수 있을 때까지 기다려준다. 프로그램을 실행한 후 바로 제어하려면 Run 대신 RunWait 함수로 기동하는 것이 좋다.

함수 레퍼런스

오토핫키가 가장 많이 쓰는 함수는 Send와 Run이고 MsgBox는 동작 확인을 위해 주로 사용한다. 몇 가지만 간략하게 더 알아 보자.

SoundBeep [주파수, 시간]

이 함수는 스피커로 짧은 비프음을 낸다. 동작을 확인하거나 사용자의 주의를 끌 때 유용하다. 주파수와 시간을 인수로 지정하며 생략시 523Hz의 소리를 0.15초간 낸다. 주파수와 시간을 바꾸면 음색이 달라진다. 스크립트로 확인해 보자. 소리를 지면에 옮길 수는 없으므로 직접 들어 봐야 한다.

F1::SoundBeep

F2::SoundBeep 1000

F3::SoundBeep 2000, 50

Sleep 지연시간

스크립트를 지정한 시간만큼 정지시킨다. 시간은 1/1000초 단위이다. 사용자의 입력을 대기하거나 실행중인 모습을 천천히 보여줄 때 유용하다.

ExitApp [종료코드]

스크립트를 종료한다. 종료코드는 호출측으로 전달하는 코드이되 생략해도 상관 없다. 실행을 계속할 수 없는 치명적인 에러 발생시 사용한다. 핫키에서 이 함수를 호출하면 핫키가 포함된 스크립트 전체가 종료된다.

다행히 함수와 인수의 이름만으로도 동작을 쉽게 유추할 수 있다. 이외에도 수많은 함수를 제공하는데 C, 자바, C# 등의 언어와 유사한 수준이다. 이 많은 함수를 일일이 다 설명할 수는 없으니 어떤 종류의 함수가 있는지 소개만 한다.

함수	설명
Format, FormatTime, StrLen, StrReplace, StrSplit, SubStr	문자열 조작
WinActive, WinClose, WinExist, WinHide, WinMove	윈도우 관리
Abs, Log, Max, Min, Round, Sqrt, Sin, Cos, Tan	수학 함수
GetKeyState, KeyWait, GetKeyVK	키보드 정보 조사
MouseClick, MouseMove, Click	마우스 제어
EnvGet, EnvSet, SysGet	시스템 정보 조사
FileCopy, FileDelete, FileExist, FileOpen, FileRead, FileAppend	파일 관리 및 입출력
MonitorGetCount, MonitorGetPrimary, MonitorGet	멀티모니터 지원
RegCreateKey, RegRead, RegWrite	레지스트리 입출력

윈도우 응용 프로그램을 만드는데 필요한 함수는 거의 다 있다고 보면 된다. 이 많은 함수를 일일이 설명할 수는 없으므로 존재만 알아 두고 필요할 때 레퍼런스를 찾아 보자. 운영체제의 함수라 프로그래밍도 적당히 할 수 있어야 이 함수를 제대로 써 먹을 수 있다.