3.핫키

키 목록

이제 본격적으로 문법을 실습해 보자. 오토핫키는 여러 가지 기능을 제공하는데 가장 기본적인 기능은 키를 재정의하는 것이며 누르면 바로 동작한다고 해서 핫키(HotKey)라고 부른다. 핫키를 정의하는 기본 문법은 다음과 같다.

키::명령

::의 왼쪽에 정의할 키를 지정하고 오른쪽에 이 키를 누를 때 실행할 명령을 기술한다. F1::Send "^{c}" 구문은 F1키를 누를 때 Ctrl+C 입력을 보내라는 뜻이다. 이때 ::의 오른쪽에는 공백이 있어도 상관 없지만 왼쪽에 공백이 있어서는 안됨을 유의하자.

오토핫키는 비교적 자유로운 포맷을 지원하지만 F1 ::으로 쓰면 'F1' 키가 아닌 공백까지 포함하여 'F1 '키를 찾는데 그런 키는 정의되어 있지 않아 에러 처리된다. 키와 ::은 딱 붙여 써야 한다. 명령이 하나 뿐일 때는 같은 줄에 쓸 수 있지만 두 개 이상이면 { } 블록을 구성해야 한다.

키::

{

명령1

명령2

...

}

명령의 개수에는 제한이 없고 얼마든지 많은 명령을 포함할 수 있다. 한줄에 명령 하나씩 쓰며 오토핫키는 위에서 아래로 순서대로 명령을 실행한다. 이 블록안에서 반복, 조건판단, 변수 선언 등 웬만한 프로그래밍 언어의 동작을 수행할 수 있다. 앞에서 ^f5키에 대해 두 개의 명령을 작성했다.

명령을 작성하는 방법은 차후에 배우기로 하고 일단 ::의 왼쪽에 지정하는 키의 이름부터 알아 보자. 키보드에 있는 모든 키 뿐만 아니라 마우스, 조이스틱 등 입력 가능한 장치를 모두 칭할 수 있다. 목록이 굉장히 방대할 뿐만 아니라 상식과는 좀 다른 이름이 있고 동의어도 많아 헷갈린다.

이름	키
A~Z	알파벳 키
1~0	숫자키
F1~F24	펑션키
Space, Tab, Enter	공백, 탭, 개행. 개행이 Return이 아님을 주의
Escape(Esc), Backspace (BS)	짧은 이름도 사용 가능하다.
Delete (Del), Insert (Ins)	삭제, 삽입
Home, End, PgUp, PgDn Up, Down, Left, Right	커서 이동키
Control (Ctrl), LControl (LCtrl), RControl (RCtrl)	Ctrl키. 좌우 모두를 칭하거나 각각 칭한다.
Alt, LAlt, RAlt	Alt
Shift, LShift, RShift	Shift
LWin, RWin	Win키, 좌우를 모두 칭하는 명칭은 없다.
CapsLock, ScrollLock, NumLock	고정키
AppsKey, PrintScreen, Pause	menu, PrtSc, Pause 키
Numpad0 ~ Numpad9	넘패드의 숫자키
NumpadDot, NumpadDiv, NumpadMult, NumpadAdd, NumpadSub, NumpadEnter	넘패드의 연자자키
LButton, RButton, MButton	마우스 버튼
XButton1, XButton2	마우스 앞뒤 버튼
WheelDown, WheelUp, WheelLeft. WheelRight	휠 굴림 및 기울임
JoyX, JoyY, and JoyZ	조이스틱 버튼
Volume_Up, Volume_Down, Media_Play_Pause	멀티미디어 버튼
Browser_Back, Browser_Forward	브라우저 버튼

이 정도만 해도 원하는 기능을 할당해 쓰기에 충분하다. 키의 전체 목록은 도움말을 참조하자. 키 이름은 대소문자는 구분하지 않는다. F1이라고 적어도 되고 f1이라고 적어도 되며 Ctrl, ctrl, CTRL 모두 인정한다. 앞 실습에서 ^f5를 고의적으로 소문자로 적었는데 동작에 아무 이상이 없다.

그러나 따옴표안에 들어가는 키이름에서 알파벳은 대소문자의 영향을 받는다. test.ahk에 다음 스크립트를 작성해 보자. 실행중에라면 앞에서 안내한대로 편집 후 F12만 누르면 저장 및 다시 로드한다. 이후에도 이 과정대로 반복 실습하면 된다.

A::Send "{x}"

b::Send "{Y}"

c::Send "{z}"

:: 왼쪽의 키는 A로 적으나 a로 적으나 똑같은 키를 의미한다. Caps키의 상태나 한글 모드와 상관없이 A키를 누르기만 하면 이 핫키를 실행한다. b, c 핫키는 소문자로 적었는데 B, C로 적어도 똑같다. 핫키와는 달리 Send로 보내는 문자는 대소문자를 가린다.

A키를 누르면 언제나 소문자 x를 입력하고 B키를 누르면 언제나 대문자 Y를 입력한다. Caps키의 상태와는 상관없이 지정한 키를 정확히 눌러 준다. 만약 한글 모드이면 x,y,z의 한글에 해당하는 ㅌ,ㅛ,ㅋ를 입력한다. b키 입력에 대해 오토핫키는 키보드의 상태에 따라 윈도우로 실제 보낼 문자를 결정한다.

스크립트에 지정한 키를 정확히 눌러 주기 위해 나름 정교한 조건을 점검하는데 이게 반드시 바람직한 처리는 아니다. b를 눌렀을 때 y를 눌러만 주면 되지 Caps나 Shift 상태까지 고려해 버리면 사용자가 직접 대소문자를 결정하기 어렵다. 또한 한글은 원하는 것과 정확히 일치하지 않을 수도 있는데 오토핫키가 한글까지 고려하여 만든 프로그램이 아니다 보니 어쩔 수 없는 면이 있다.

입력키의 대소문자를 구분하는 것은 알파벳키만 그렇다. 펑션키는 F5로 적으나 f5로 적으나 똑같으며 F5로 적었다고 해서 Shift키를 같이 눌러주지는 않는다. 키는 누를 때 동작하며 계속 누르고 있으면 자동으로 반복된다. 이 기능을 오토 리피트라고 하며 반복 시작 시간과 속도는 제어판에서 선택한다. F1을 누를 때 공백을 입력해 보자.

F1::Send "{Space}"

F1키를 누르기만 하면 공백이 입력되며 떼지 않고 계속 누르고 있으면 공백이 반복적으로 입력된다. 키를 누를 때가 아닌 놓을 때 핫키를 실행하고 싶다면 핫키 뒤에 up을 붙인다.

F1 up::Send "{Space}"

이렇게 하면 F1을 누를 때는 아무 동작도 하지 않으며 F1키를 놓을 때 동작한다. 이미 키를 놓았으므로 오토 리피트는 동작하지 않는다. 일반적인 키는 누를 때 동작하는 것이 당연하지만 누를 때와 놓을 때의 동작이 다른 키도 있다. 대표적으로 Win키가 그런데 누를 때는 다른 키와 조합하지만 단독으로 눌렀다 놓을 때는 시작 메뉴가 열린다. 누를 때 열리는게 아니라 놓을 때 열린다.

키보드에 있는 키뿐만 아니라 마우스의 버튼도 핫키로 지정할 수 있다. 좌우 클릭을 다른 용도로 바꾸는 건 과격하지만 중앙 버튼 클릭이나 휠은 필요에 따라 용도를 바꿔 쓰면 편리하다. 다음 스크립트는 중앙 버튼으로 캐럿을 이동한다.

MButton::Send "{End}"

WheelDown::Send "{Down}"

WheelUp::Send "{Up}"

휠을 굴리면 스크롤이 발생하는 것이 아니라 아래 위로 이동한다. 스크롤보다 이동할 일이 많다면 잠시 바꿔 쓰면 된다. 중앙 버튼을 클릭하면 줄 끝으로 캐럿을 이동한다. 휠은 아래 위로 굴려서 입력한다는 면에서 볼륨 조절, 언두/리두, 줌, 이전/다음 등 반대되는 동작을 수행하기에 실용적이다.

마우스뿐만 아니라 조이스틱도 핫키의 대상이다. PC에는 보통 조이스틱을 연결해 놓지 않지만 특정 동작을 자주 수행한다면 발 밑에 조이스틱을 두고 액셀 밟듯이 발로 입력하는 것도 가능하다. 멀티미디어키나 브라우저키도 비슷한 용도로 활용할 수 있다.

조합키

핫키를 사용하면 문자키까지도 다른 문자로 바꿀 수는 있지만 문자 배치가 바뀌면 키보드를 제대로 쓰기 어렵다. 문자나 숫자키는 늘상 사용하는 중요한 키여서 핫키로 사용하기 어렵다. 개별키는 원래의 기능을 수행하도록 내버려 두고 조합키로 핫키를 만드는 것이 보통이다.

키보드에서 다른 키와 함께 누르는 조합키는 4개 있으며 각각 기호로 표기한다. F1은 F1키를 단독으로 누르는 것이지만 앞에 ^를 붙여 ^F1으로 지정하면 Ctrl+F1키를 의미한다. 두 개 이상의 조합키를 동시에 지정할 수도 있으며 이때 조합키의 순서는 중요하지 않다.

기호	왼쪽	오른쪽	조합키
^	<^	>^	Ctrl 키, 좌우를 각각 지정할 수도 있다.
!	<!	>!	Alt키
+	<+	>+	Shift키
#	<#	>#	Win키

F1키에 대한 핫키를 여러 가지 조합으로 정의해 보자. 핫키가 동작하지는 확인하기 위해 문자만 찍어 보았다.

F1::Send "{a}"

^F1::Send "{b}"

+F1::Send "{c}"

^+F1::Send "^+{Esc}"

#!F1::Send "help me"

F1을 단독으로 누르면 a가 나타나고 Ctrl과 함께 누르면 b, Shift와 함께 누르면 c를 입력한다. Ctrl과 Shift를 같이 누르면 Ctrl+Shift+Esc를 눌러 작업 관리자를 실행한다. ^+F1은 +^F1으로 적어도 된다. Alt와 Win키를 같이 누르면 help me 문자열을 출력한다.

Shift, Ctrl, Alt는 좌우에 2개씩 있는데 좌우의 조합키에 대해 각각 다른 핫키를 지정할 수 있다. 조합키 기호 앞의 <는 왼쪽이라는 뜻이며 >는 오른쪽이라는 뜻이다. 그냥 ^ 조합은 좌우 어느 것이나 동작하지만 <^ 또는 >^로 방향을 분명히 지정하면 한쪽 조합키에 대해서만 핫키가 걸린다.

<^F1::Send "{left}"

>^F1::Send "{right}"

왼쪽 Ctrl키와 함께 F1을 누르면 캐럿이 왼쪽으로 이동하고 오른쪽 Ctrl키와 함께 F1을 누르면 캐럿이 오른쪽으로 이동한다. 똑같은 Ctrl키이지만 어느 쪽을 누르는가에 따라 실제 명령이 달라진다.

일반적으로 좌우까지 구분하지는 않지만 빈도가 떨어지는 핫키는 잘 누르지 않는 오른쪽 조합키에 살짝 숨겨 두어 실수를 방지하는 것이 좋다. Shift에 대해서는 좌우를 구분하는 경우가 별로 없지만 Ctrl과 Alt는 현재도 좌우를 구분하는 예가 꽤 있다. 윈도우 키는 보통 하나밖에 없어 좌우를 잘 구분하지 않는다.

와일드 카드

조합키와 함께 지정한 핫키는 정확하게 조합키대로만 동작한다. F1 핫키에 대해 Del키를 할당해 보자.

F1::Send "{Del}"

이 상태에서 F1을 누르면 현재 위치의 문자 하나를 삭제한다. 그러나 이 핫키는 F1을 단독으로 누를 때만 동작하며 Shift나 Ctrl과 조합하면 동작하지 않는다. F1과 Shift+F1은 다른 핫키이기 때문이다. 어떤 조합키를 누르든지 동작하려면 +F1, ^F1, !F1 등 모든 조합에 대해서는 물론이고 ^+!F1 같은 복수 조합까지 다 정의해야 한다.

이 정의를 한꺼번에 해 주는 것이 와일드 카드이다. 조합키 자리에 * 기호를 쓰면 임의의 조합키를 눌러도 핫키가 동작한다. 다음 스크립트는 어떤 조합키 또는 조합키 집합과 함께 누르든 F1키만 누르면 삭제 명령으로 동작한다.

*F1::Send "{Del}"

만약 F1과 Shift+F1, Ctrl+F1, Ctrl+Shift+F1을 모두 다르게 정의하고 싶다면 각 핫키를 개별적으로 다 정의하면 된다.

~ 기호는 핫키의 원래 기능을 유지한다. 일반적인 핫키는 원래 기능을 정지하고 지정한 명령만 실행한다. 이에 비해 ~ 기호를 붙이면 일단 원래키의 동작을 수행하고 난 후에 핫키의 동작을 이어서 실행한다. 다음 스크립트를 작성해 보자.

AppsKey::Send "{BS}"

이 명령은 메뉴키를 BS로 바꾼다. 원래 메뉴를 여는 기능은 정지되고 BS키로만 동작한다. 이 명령 앞에 ~를 붙이면 메뉴 기능도 같이 실행한다.

~AppsKey::Send "{BS}"

이제 메뉴키를 누르면 메뉴가 열리면서 삭제를 같이 수행한다. ~F1::Send "{Del}" 핫키는 도움말도 열고 삭제도 한다. 핫키는 키의 동작을 바꾸는 것인데 비해 ~를 붙이면 원래 동작에 추가 동작을 더하는 것이다.

조합키는 다른 키와 같이 누르는 방식으로 키의 기능에 다양성을 부여하며 키의 원래 기능을 방해하지 않는다. A를 단독으로 누를 때는 문자 A 또는 a를 입력하는 기능을 유지하면서 ^A, +A, !A, #A는 다른 기능으로 정의할 수 있고 조합키의 집합까지 사용할 수 있다.

그러나 조합키가 4개밖에 되지 않은데다 조합키의 일부는 기능이 이미 고정되어 있어 남은 키가 그리 많지 않다. 예를 들어 ^S는 대부분의 프로그램에서 저장 명령으로 사용하는데 이 키의 기능을 바꿔 버리면 불편해진다. & 기호는 일반키를 연결하여 더 다양한 조합을 만들어 낸다.

F1 & F2::Send("Help me!")

이 핫키는 F1을 누른 상태에서 F2를 누를 때를 의미한다. 마치 F1이 Ctrl, Shift 같은 조합키처럼 동작한다. F1을 눌렀다 놓은 후 F2를 눌러서는 안되며 반드시 순서대로 눌러야 한다. 두 키의 연속 입력만 핫키로 정의한 것이므로 F1, F2 개별키는 원래의 기능을 유지한다. 일반키를 원하는대로 조합할 수 있어 기존 기능을 훼손하지 않고 얼마든지 많은 핫키를 정의할 수 있다.

두 개의 핫키를 OR로 연결할 때는 아래 위로 핫키 두 개를 동시에 정의한다. 정의문이 비어 있는 핫키는 아래쪽 핫키와 명령을 공유한다. F1, F2 둘 다 위로 이동하려면 다음과 같이 쓴다.

F1::

F2::Send "{up}"

물론 두 키에 똑같은 기능을 할당할 경우가 흔치는 않고 사실 그럴 필요도 없다. 넘패드의 키는 NumLock 상태에 따라 키가 달라지는데 NumLock과 상관없이 동작하고 싶을 때 이 기능을 사용한다.

Numpad0::

NumpadIns::Send "{up}"

넘패드의 0은 숫자 모드에서는 0이지만 NumLock를 끄면 Ins키로 동작한다. 상태에 따라 키 이름은 다르지만 위치는 같으니 어떤 모드이거나 똑같은 명령을 할당하고 싶다면 OR로 연결한다.

상황별 핫키

키보드는 시스템 전체가 공유하는 자원이어서 핫키는 전역적으로 동작한다. 즉, 메모장에서나 워드에서나 똑같이 핫키를 사용할 수 있다. 그러나 전역적인 핫키는 활용상의 문제가 있다. 메모장이 Ctrl+T를 사용하지 않아 여기다 어떤 기능을 작성했다고 하자. 메모장에서는 당연히 잘 동작하겠지만 다른 프로그램의 Ctrl+T의 기능도 바뀌어 버린다.

Ctrl+T는 워드에서 문단 정렬 기능으로 사용되며 웹브라우저에서 새탭 기능을 가지는데 메모장이 이 키의 기능을 바꿔 버리면 모두 먹통이 되어 버린다. 핫키가 항상 전역이어서는 안되며 조건에 따라 달라져아 한다. 프로그램마다 필요한 핫키 목록이 다르다면 상황별 핫키를 정의한다. 기본 형식은 다음과 같다.

#HotIf 조건

핫키 목록

#HotIf

#HotIf 지시자로 조건을 지정하고 이 블록 사이에 조건에 따라 실행할 핫키를 지정한다. 이 블록내의 핫키는 조건이 만족할 때만 동작하며 그 외의 상태일 때는 동작하지 않는다. 다음 스크립트를 작성해 보자.

#HotIf WinActive("ahk_class Notepad")

F1::Send "{left}"

F2::Send "{right}"

#HotIf

F1::Send "{up}"

F2::Send "{down}"

F1, F2에 대해 두 벌의 핫키를 정의하되 조건이 다르다. 위쪽의 핫키는 WinActive("ahk_class Notepad") 조건이 참일 때, 즉 메모장이 활성화되어 있을 때만 동작하며 아래쪽의 핫키는 그 외의 조건일 때 동작한다. 메모장에서는 F1, F2가 좌우로 이동하지만 그 외의 프로그램에서는 상하로 이동한다.

#HotIf 조건에 따라 핫키를 정의하면 특정 프로그램에서만 동작하도록 할 수 있고 프로그램별로 핫키 세트를 따로 만들어 쓸 수도 있다. 메모장에서는 이렇게 쓰고 워드에서는 저렇게 쓰고 하는 것이 가능해진다. 핫키 세트는 원하는 개수만큼 만들 수 있다.

조건에 포함되지 않는 핫키는 전역적으로 동작한다. 조건은 여러 형태로 정의할 수 있는데 프로그램 뿐만 아니라 키보드나 마우스의 상태까지 고려할 수 있다. 다음 예를 보자.

조건	설명
WinExist("ahk_class Notepad")	메모장이 실행중일 때
WinActive("ahk_class Notepad")	메모장이 활성화되어 있을 때
MouseIsOver("ahk_class Notepad")	메모장 위에 마우스 커서가 있을 때
ActiveControlIsOfClass("Edit")	에디트가 활성화되어 있을 때

특정 윈도우를 칭할 때는 윈도우 클래스로 찾을 수도 있고 타이틀바의 문자열로 찾을 수도 있다. 메모장은 WinActive("메모장") 조건으로 쉽게 찾을 수 있지만 이건 한글 윈도우에서만 통한다. 그보다는 윈도우 클래스로 찾는 것이 더 정확하며 이때는 "ahk_class 클래스명" 조건을 사용한다. 윈도우 클래스는 Win32 내부에서 윈도우를 생성하는 고유의 템플릿인데 윈도우의 유형 정도로 이해하면 된다.

이 조건을 사용하려면 원하는 윈도우의 클래스명을 알아야 하는데 오토핫키는 이런 목적으로 스파이 프로그램을 제공한다. 스파이는 대시보드에도 있고 트레이아이콘의 팝업 메뉴에도 있다. 실행해 놓고 조사할 창으로 커서만 가져가면 윈도우의 내부적인 정보를 보여 준다.

이 정보를 보면 타이틀바의 제목, 윈도우 클래스, 실행 파일명, ID 등 여러 가지 정보를 알 수 있으며 이 정보를 조건에 사용하면 된다. 프로그램별로 윈도우 클래스는 고유한 편이어서 웬만해서는 중복이 없으며 특정 윈도우를 칭하는 조건으로 사용해도 된다.